In bash $0 contains the name of the script, but in awk if I make a script named myscript.awk with the following content:
#!/usr/bin/awk -f
BEGIN{ print ARGV[0] }
and run it, it will only print "awk". Besides, ARGV[i] with i>0 is used only for script arguments in command line. So, how to make it print the name of the script, in this case "myscript.awk"?
I don't know any direct way of getting the command name from within awk. You can however find it through a sub-shell.
With GNU awk and the ps command you can use the process ID from PROCINFO["PID"] to retrieve the command name as a workaround. For example:
cmdname.awk
#!/usr/bin/gawk -f
BEGIN {
("ps -p " PROCINFO["pid"] " -o comm=") | getline CMDNAME
print CMDNAME
}
You can use the same approach, but derive awk's PID from the $PPID special shell variable (PID of the parent):
cmdname.awk
#!/usr/bin/mawk -f
BEGIN {
("ps -p $PPID -o comm=") | getline CMDNAME
print CMDNAME
}
Run the script like this:
./cmdname.awk
Output in both cases:
cmdname.awk
With GNU awk 4.1.3 in bash on cygwin:
$ cat tst.sh
#!/bin/awk -f
BEGIN { print "Executing:", ENVIRON["_"] }
$ ./tst.sh
Executing: ./tst.sh
I don't know how portable that is. As always, though, I wouldn't execute an awk script using a shebang in a shell script as it just robs you of possible functionality. Keep it simple and just do this instead:
$ cat tst2.sh
awk -v cmd="$0" '
BEGIN { print "Executing:", cmd }
' "$@"
$ ./tst2.sh
Executing: ./tst2.sh
That last will work with any modern awk in any shell on any platform.
I don't think this is possible as per gawk documentation:
Finally, the value of
ARGV[0](see section 7.5 Built-in Variables) varies depending upon your operating system. Some systems putawkthere, some put the full pathname of awk (such as/bin/awk), and some put the name of your script ('advice'). Don't rely on the value ofARGV[0]to provide your script name.
On linux you can try using a kind of a dirty hack and as pointed in comments by Stéphane Chazelas it is possible if implementation of awk supports NUL bytes:
#!/usr/bin/awk -f
BEGIN { getline t < "/proc/self/cmdline"; split(t, a, "\0"); print a[3]; }
With POSIX awk:
#!/usr/bin/awk -f
BEGIN {
print ENVIRON["AWKSCRIPT"]
}
Then:
AWKSCRIPT=test.awk ./test.awk
test.awk
Checking the GNU awk user's guide - 7.5.2 Built-in Variables That Convey Information I stumbled upon:
PROCINFO #
The elements of this array provide access to information about the running awk program. The following elements (listed alphabetically) are guaranteed to be available:
PROCINFO["pid"]
The process ID of the current process.
This means that you can know the PID of the program during runtime. Then, it is a matter of using system() to look for the process with this given PID:
#!/usr/bin/gawk -f
BEGIN{ pid=PROCINFO["pid"]
system("ps -ef | awk '$2==" pid " {print $NF}'")
}
I use ps -ef, which displays the PID on the 2nd column. Assuming the executiong is done through awk -f <script> and no other parameters, we can assume the last field of the line contains the information we want.
In case we had some parameters, we would have to parse the line differently -or, better, use some of the options of ps to print just the columns we are interested in.
$ awk -f a.awk
a.awk
$ cp a.awk hello.awk
$ awk -f hello.awk
hello.awk
Note also that another chapter of the GNU awk user's guide tells us that ARGV is not the way to go:
Finally, the value of ARGV[0] (see Built-in Variables) varies depending upon your operating system. Some systems put ‘awk’ there, some put the full pathname of awk (such as /bin/awk), and some put the name of your script (‘advice’). (d.c.) Don’t rely on the value of ARGV[0] to provide your script name.
